โปรเจกต์ ส่ง Email จาก Gmail Account ของคุณด้วย Temboo

1. ตั้งค่าการใช้งาน

• ตรวจสอบให้แน่ใจว่าคุณมีบัญชี Temboo แล้ว หากคุณยังไม่มี สามารถลงทะเบียนใช้งานฟรีได้ที่นี่

• คุณยังจำเป็นต้องใช้บัญชี Gmail ซึ่งคุณสามารถสร้างได้ที่นี่

• ตรวจสอบให้แน่ใจว่า Yún ของคุณเชื่อมต่อกับ Internet เรียบร้อยแล้ว

2. เขียน Sketch

คัดลอก Sketch Code ด้านล่างนี้ไปยังแท็บใหม่ใน Arduino IDE ของคุณ Code นี้จะเรียกใช้ SendEmail Choreo และคุณจำเป็นต้องเปลี่ยนค่า Placeholder ใน Code ด้วยรายละเอียดบัญชี Gmail ของคุณเอง

/*
  SendAnEmail
  สาธิตการส่ง Email ผ่านบัญชี Google Gmail โดยใช้ Temboo Arduino Yun SDK
  Code ตัวอย่างนี้เป็นสาธารณสมบัติ (Public Domain)
*/
#include <Bridge.h>
#include <Temboo.h>
#include "TembooAccount.h" // ประกอบด้วยข้อมูลบัญชี Temboo
/*** แทนที่ค่าของคุณด้านล่าง: ***/
// หมายเหตุ: เพื่อความปลอดภัยที่เพิ่มขึ้นและความสามารถในการนำกลับมาใช้ใหม่ คุณสามารถ
// ใช้คำสั่ง #define เพื่อระบุค่าเหล่านี้ในไฟล์ .h ได้
// Gmail Username ของคุณ โดยใช้รูปแบบที่อยู่อีเมลที่สมบูรณ์ เช่น "bob.smith@gmail.com"
const String GMAIL_USER_NAME = "xxxxxxxxxx";
// Gmail Password ของคุณ
const String GMAIL_PASSWORD = "xxxxxxxxxx";
// ที่อยู่อีเมลที่คุณต้องการส่งไปถึง เช่น "jane.doe@temboo.com"
const String TO_EMAIL_ADDRESS = "xxxxxxxxxx";
boolean success = false; // Flag สำหรับระบุว่าเราได้ส่ง Email ไปแล้วหรือไม่
void setup() {
  Serial.begin(9600);
  // สำหรับ Debugging ให้รอจนกว่า Serial Console จะเชื่อมต่อ
  delay(4000);
  while(!Serial);
  Bridge.begin();
}
void loop()
{
  // พยายามส่ง Email เฉพาะในกรณีที่เรายังส่งไม่สำเร็จเท่านั้น
  if (!success) {
    Serial.println("Running SendAnEmail...");
  
    TembooChoreo SendEmailChoreo;
    // เรียกใช้งาน Temboo Client
    // หมายเหตุ: Client จะต้องถูกเรียกใช้ใหม่ และใส่ Argument ที่เหมาะสม
    // ทุกครั้งที่เรียก Method run()
    SendEmailChoreo.begin();
    
    // ตั้งค่าข้อมูลประจำตัวของบัญชี Temboo
    SendEmailChoreo.setAccountName(TEMBOO_ACCOUNT);
    SendEmailChoreo.setAppKeyName(TEMBOO_APP_KEY_NAME);
    SendEmailChoreo.setAppKey(TEMBOO_APP_KEY);
    // ระบุ Temboo Library Choreo ที่จะรัน (Google > Gmail > SendEmail)
    SendEmailChoreo.setChoreo("/Library/Google/Gmail/SendEmail");
    // ตั้งค่า Input ที่จำเป็นสำหรับ Choreo
    // ดูรายละเอียดทั้งหมดเกี่ยวกับ Input สำหรับ Choreo นี้ที่
    // https://www.temboo.com/library/Library/Google/Gmail/SendEmail/ 
    // Input แรกคือที่อยู่อีเมล Gmail ของคุณ
    SendEmailChoreo.addInput("Username", GMAIL_USER_NAME);
    // ถัดไปคือ Password ของ Gmail
    SendEmailChoreo.addInput("Password", GMAIL_PASSWORD);
    // ส่งอีเมลถึงใคร
    SendEmailChoreo.addInput("ToAddress", TO_EMAIL_ADDRESS);
    // ตามด้วยหัวข้ออีเมล
    SendEmailChoreo.addInput("Subject", "ALERT: Greenhouse Temperature");
     // ถัดมาคือเนื้อหาข้อความ ซึ่งเป็นเนื้อหาหลักของอีเมล
    SendEmailChoreo.addInput("MessageBody", "Hey! The greenhouse is too cold!");
    // สั่งให้ Choreo ทำงานและรอผลลัพธ์ โดย Return Code (returnCode)
    // จะบอกเราว่า Temboo Client สามารถส่งคำขอของเราไปยัง Temboo Server ได้หรือไม่
    unsigned int returnCode = SendEmailChoreo.run();
    // Return Code เป็นศูนย์ (0) หมายความว่าทุกอย่างทำงานได้ปกติ
    if (returnCode == 0) {
        Serial.println("Success! Email sent!");
        success = true;
    } else {
      // Return Code ที่ไม่ใช่ศูนย์หมายความว่าเกิดข้อผิดพลาด
      // อ่านและพิมพ์ข้อความแจ้งข้อผิดพลาด
      while (SendEmailChoreo.available()) {
        char c = SendEmailChoreo.read();
        Serial.print(c);
      }
    } 
    SendEmailChoreo.close();
    // ไม่ต้องทำอะไรใน 60 วินาทีถัดไป
    delay(60000);
  }
}

3. สร้าง Header File ของคุณ

Sketch ด้านบนมีการอ้างอิงถึง Header File TembooAccount.h ซึ่งมีข้อมูลบัญชี Temboo ของคุณ

หากคุณเข้าสู่ระบบอยู่ คุณจะเห็นรายละเอียดบัญชีของคุณใน Code Snippet ด้านล่าง (มิฉะนั้นคุณจะเห็นค่า Placeholder) คัดลอก Code Snippet นี้ไปยังแท็บใหม่ใน Arduino และตั้งชื่อว่า TembooAccount.h

เมื่อเตรียมทั้งสองไฟล์เรียบร้อยแล้ว คุณก็พร้อมที่จะ Upload Sketch และส่ง Email จาก Yún ของคุณ ไม่จำเป็นต้องส่งคำขอบคุณมาให้เราก็ได้

หมายเหตุ: ในครั้งแรกที่คุณรัน Sketch นี้ คุณอาจได้รับคำเตือนจาก Google ให้ยืนยันการเข้าถึงจากระบบภายนอก ให้ปฏิบัติตามคำแนะนำในการเข้าชมหน้านี้เพื่อให้สิทธิ์ Yún เข้าถึงบัญชี Google ของคุณ

#define TEMBOO_ACCOUNT "accountName"  // ชื่อบัญชี Temboo ของคุณ 
#define TEMBOO_APP_KEY_NAME "myFirstApp"  // ชื่อ App Key ของ Temboo ของคุณ
#define TEMBOO_APP_KEY  "abc123xxxxxxxxxxxxxx"  // App Key ของ Temboo ของคุณ

4. ขั้นตอนต่อไปคืออะไร?

ตอนนี้ Yún ของคุณสามารถส่งอีเมลได้แล้ว ลองเข้าไปดู Choreo อื่นๆ กว่า 2,000 รายการใน Library ของเรา และเริ่มคิดถึงความเป็นไปได้ต่างๆ สำหรับโปรเจกต์ Yún ครั้งต่อไปของคุณ

5. ต้องการความช่วยเหลือหรือไม่?

เรายินดีช่วยเหลือเสมอ เพียงส่งอีเมลมาหาเราที่ support@temboo.com และเราจะตอบคำถามของคุณ